10 Advanced IF formula tricks you must know

IF is the most used Excel function out there. Here are 10 advanced IF tricks to take your formulas to next-level

In this article, you will learn:

Only one of, two out of three type rules
Between condition check with MEDIAN
Replacing Nested IF with shorter function
Using boolean logic to replace IF formulas
Arrays with IF function
Wildcard checks with IF function
How to use IF formula in other places
- Conditional formatting
- Data validation
- Charts

Sample data for the examples

All examples in this article use below sample data. Assume it is in the range C8:G23

You can download this data alone for practice purpose from here.

Includes sample data for practice, completed Excel workbook

#1 – Only one of condition

Situation

Identify employees who are only one of gender=male or salary under $85,000

Formula

				
					=IF(XOR(D8="Male",G8<85000),"Include", "Exclude")

Explanation

XOR function will return TRUE if an odd number inputs are TRUE, else FALSE.

So, our XOR(D8=”Male”, G8<85000) will be useful for checking only one of condition.

Note: XOR doesn’t work when you want to check only one of when you have more than 2 conditions. For that refer to next trick.

Also read: Either Or formula in Excel

#2 – Two out of Three Check

Situation

Flag employees when they meet any two out of below three conditions.

Department is Website
Year of join is 2019
Salary is above $90,000

Formula

				
					=IF((E8="Website")+(YEAR(F8)=2019)+(G8>90000)>=2,
        "Include", "Exclude")

Explanation

The trick is in understanding Excel treats TRUE as 1 and FALSE as 0.

So, the expression (E8=”Website”)+(YEAR(F8)=2019)+(G8>90000)

will be converted a bunch of 1s & 0s and added up, depending on the details of employee.

We can then simply check if such number is >=2 to see if any two out of three conditions are met.

More: Two out of three – other ways to do it

#3 – Using MEDIAN for Between Condition

Situation

Identify employees joined between 1-Jan-2019 and 30-Jun-2019.

Formula

				
					=IF(MEDIAN(F8,DATE(2019,1,1),DATE(2019,6,30))=F8,
        "Review","")

Explanation

Normally, we use AND() function to check for between condition. But, you can also use MEDIAN for this.

The pattern goes like,

=MEDIAN(your value, above, below) = your value

The above will be TRUE if your value is between above and below values.

For example, =MEDIAN(7, 3,9) = 7 is TRUE.

Read more: How to write BETWEEN formula in Excel

#4 – Replacing Nested IF functions

Situation

Calculate staff bonus based on below rules:

1% for Website staff
3 % for Sales staff joined in 2018
2% for others

Formula

				
					=IFS(E8="Website",1%,
        AND(E8="Sales",YEAR(F8)=2018),3%,
        TRUE,2%)

Explanation

Nested IF functions can be hard to write and tricky to maintain. That is why, you should use the newly introduced IFS() function.

The syntax for IFS goes like this:

=IFS(condition1, value1, condition2, value2…)

But, IFS() doesn’t have ELSE option…?

Well, you can use TRUE as last condition to fix this.

In the above formula TRUE, 2% part handles the ELSE case beautifully.

#5 – Boolean Logic to avoid IF formulas

Situation

Calculate staff bonus based on below rules, but don’t use any IF formulas:

1% for Website staff
3 % for Sales staff joined in 2018
2% for others

Formula

				
					=2% - (E8="Website")*1% + AND(E8="Sales",YEAR(F8)=2018)*1%

Explanation

You can use boolean logic checks to altogether avoid IF formulas. This works well when your outputs are numbers.

The above formula calculates staff bonus by using TRUE=1 & FALSE=0 notion.

Let’s test it out for below staff:

For Gigi:

2% – (FALSE)*1% + (TRUE)* 1% = 3%

For Curtice:

2% – (FALSE)*1% + (FALSE)*1% = 2%

Read more: Daniel Ferry’s excellent I heart IF

#6 – Checking if a value is in another list

Situation

Check if an employee is part of on call support team
(range: C32:C36)

Formula

				
					=IF(COUNTIFS($C$32:$C$36,C8),"On call","Not on call")

Explanation

We can use COUNTIFS or MATCH functions to do this. I prefer COUNTIFS.

Just count if a given data point is in another list.

Why don’t we check >0?

Remember, Excel treats any number other than 0 as TRUE. So we don’t need to write COUNTIFS($C$32:$C$36,C8)>0.

#7 – Arrays with IF formula

Situation

Calculate median salary of website staff

Formula

				
					=MEDIAN(IF(E8:E23="Website",G8:G23))

Explanation

When you use arrays in the IF formula, it will return an array of outcomes too.

So for eg. =IF({TRUE,TRUE,FALSE}, {1, 2, 3}, {“A”,”B”,”C”}) will return {1, 2, “C”}

We can use this powerful idea to calculate median salary of website staff too.

What about ELSE part? It’s missing no?

If you don’t mention the ELSE part of IF formula, it will simply return FALSE for those values.

So, in our case, we get

{FALSE;90700;48950;FALSE;FALSE;107700;…FALSE}

When MEDIAN reads those values, it will ignore the FALSEs and calculate MEDIAN for rest.

Read more: Calculating RANKIFS with Excel

Situation 2

Show all names of “Finance” staff in one cell, comma seperated.

Formula

				
					=TEXTJOIN(",",,IF(E8:E23="Finance",C8:C23,""))

Explanation

This works same as the MEDIAN(IF()) structure. For more applications of this technique, see the Excel Risk Map

#8 – Wildcard based conditions

Situation

Identify if an employee’s name contains letters bo

Formula

				
					=IF(COUNTIFS(C8,"*bo*"),"bo person","not a bo person")

Explanation

IF function is not aware of wildcards. But we can use one of the other wildcard aware functions inside IF to solve the problem. You can use either of XLOOKUP, XMATCH, MATCH, VLOOKUP, COUNTIFS for this.

I prefer COUNTIFS.

The COUNTIFS(C8, “*bo*”) will be 1 if name in C8 has bo in it, else 0.

Rest is self-explanatory.

Read more: Making VLOOKUP formula go wild | Not so wild lookups

#9 – IF formula with Conditional Formatting

Situation

Highlight employees that meet conditions specified in below cells.

Rule

				
					=AND($E8=$J$50,$D8=$J$51)

Explanation

When checking rules in conditional formatting you don’t need to use IF formula. Just use the condition part of the formula alone.

Here is the result of our rule.

Read more: 5 simple & useful conditional formatting tricks

#10 – Using IF with Charts

Situation

Make a chart with employee salaries, but highlight staff making above average salary in a different color.

Process

Add an extra column in your data and use IF formula to check if a person’s salary is above average.
Make chart with both original salary & the new column.
Overlap the bars (or columns) 100%
Color them accordingly.

Formula

				
					=IF(G8>AVERAGE($G$8:$G$23),G8,NA())

Outcome

This is how my chart looks.

Read more: How to highlight important points on your chart

Resources – File & Video

Includes sample data for practice, completed Excel workbook

Watch the video & learn these techniques

What is your favorite IF formula trick?

Share it in the comments. Let’s learn from each other.

The post 10 Advanced IF formula tricks you must know appeared first on Chandoo.org – Learn Excel, Power BI & Charting Online.

Original source: http://feedproxy.google.com/~r/PointyHairedDilbert/~3/oXEsqka943A/