Over the last few days Microsoft released XLOOKUP formula to the early adopters of Excel. Think of XLOOKUP as VLOOKUP 2.0. In this post, learn all about the function, syntax, optional parameters and 13 xlookup examples.

What is XLOOKUP?
XLOOKUP is the newest member of Excel lookup function family. You may already know its siblings – VLOOKUP, HLOOKUP, INDEX+MATCH, LOOKUP etc.
XLOOKUP allows us to search for an item in a range (or table) and return matching result. In a way, it is similar to VLOOKUP, but offers so much more.
When using XLOOKUP, you just provide 3 basic parameters and Excel does the rest.
- The value you are looking for
- The list where this value should be found
- The list from which you want the result
XLOOKUP example:
=XLOOKUP(“Jamie”, Sales[Sales Person], Sales[Net Sales])
Returns [Net Sales] for Jamie if the name exists in [Sales Person] column.
If you compare this with VLOOKUP, then you see that we no longer need to specify column_number or true/false to perform the search.
This also means, unlike VLOOKUP, XLOOKUP can actually look anywhere in the data and find the result, not just on the left.
No more complex INDEX+MATCH formulas or weird VLOOKUP concoctions.
How is XLOOKUP better?
- XLOOKUP makes the most used formula dynamic in Excel straight forward and less error prone. You just write =XLOOKUP(what you want to find, the list, the result list) and boom, you get the answer (or #N/A error if the value is not found)
- XLOOKUP offers optional parameters to search for special situations. You can search from top or bottom, you can do wild card searches and faster options to search sorted lists.
- It returns reference as output, not the value. While this may not mean much for normal users, pro Excel user’s eyes light up when they discover a formula that can return refs. That means, you can combine XLOOKUP outputs in innovative ways with other formulas.
- It is so much cooler to type, you just type =XL. I am not sure if this is a happy coincidence, but saying =XL to get this formula is just awesome.
XLOOKUP Syntax
Simple case:
=XLOOKUP(what you want to look, lookup list, result list)
=XLOOKUP("Jackie", sales[Sales Person], sales[Net Sales])
returns Jackie’s [Net Sales] if the name can be found in [Sales Person]
Optional parameters:
By default, you just need 3 parameters for XLOOKUP, as shown above. But you can also use 4th and 5th parameter to specify how you want the lookup to be done.
4th parameter for XLOOKUP: Match mode or type:
Use this to tell Excel how you want your MATCH to happen. The default is 0 (exact match) but you can also use these other options, shown below.

5th parameter for XLOOKUP: Match direction
Try this if you want to search from bottom to top. The default direction is top down (1).

13 XLOOKUP examples to really understand it
My computer received XLOOKUP update just 90 minutes ago and I have been playing with it ever since. Here are 13 different, fun & creative examples to really understand it. Have a read. If you already have XLOOKUP, feel free to download the sample workbook and have a play.
For all of these examples, we will use the [Sales] table data shown below. XLOOKUP works just as well with cell references too, but I am using structural references for ease of understanding.

XLOOKUP Examples – Table
All the examples are listed in this table. Browse it and feel free to copy the formulas to test.
Criteria | Question | Answer | Formula | Notes |
---|---|---|---|---|
Jackie | What is the net sales? | 1610 | XLOOKUP(H5,sales[Sales Person],sales[Net Sales]) | Nice and simple. Finds H5 (Jackie) in the sales[Sales Person] list and returns macthing [Net Sales] if found. |
2133 | Whose sales are this? | Jamie | XLOOKUP(H6,sales[Net Sales],sales[Sales Person]) | This time, we lookup in the middle but return the name at front. Normally we would use INDEX+MATCH for something like this, but XLOOKUP just kills it. |
Who has most sales? | Jamie | XLOOKUP(MAX(sales[Net Sales]),sales[Net Sales],sales[Sales Person]) | Of course, we can mix formulas too. MAX() finds the maximum sales and then XLOOKUP does the rest. Try other formulas like MIN(), SMALL(), LARGE() too. | |
8 | Who has this many customers? | Joseph | XLOOKUP(H8,sales[No. Customers],sales[Sales Person]) | Another example with find the middle, return from front. |
8 | Who is the last person to have this many customers? | Jamie | XLOOKUP(H9,sales[No. Customers],sales[Sales Person],0,-1) | Now we are talking!!!, you can use the optional parameters for XLOOKUP to specify match type (0 is for exact match) and match direction (-1 is for bottom to top). |
1800 | Whose sales are closest to this number, but not more? | Jagjit | XLOOKUP(H10,sales[Net Sales],sales[Sales Person],-1) | We can search for a value that is closest but not more by using match type -1. |
Ju | What is the profit of person whose name begins with this? | 1023 | XLOOKUP(H11&”*”,sales[Sales Person],sales[Profit / Loss],2) | You can do wild card searches too. * for any number of letters and ? for single letter. |
Who has least sales? | Jimmy | XLOOKUP(0,sales[Net Sales],sales[Sales Person],1) | Time for a trick!!! When searching fields like [Net Sales] which will usually have just positive values, you can look for 0 with match type as 1 (next highest value). | |
What is the sales for very last person? | 1415 | XLOOKUP(“*”,sales[Sales Person],sales[Net Sales],2,-1) | Another trick! Search for “*” from end to get the last value’s matching sales. | |
Who is the very last person? | Karl | XLOOKUP(“*”,sales[Sales Person], sales[Sales Person],2,-1) | Of course, you can search and return from the same column to find out the last person’s name. | |
Net Sales | What is H11 for Johnson? | 1540 | XLOOKUP(“Johnson”,sales[Sales Person],XLOOKUP(H15,sales[#Headers],sales)) | 2 way lookups by nesting XLOOKUP. Remember, inner XLOOKUP returns a list of [Net Sales] |
Jamie | What is the Net Sales for second person with this name? | 2724 | XLOOKUP(H16&”2″,FILTER(sales[Sales Person],sales[Sales Person]=H16)&SEQUENCE(3),FILTER(sales[Net Sales],sales[Sales Person]=H16)) | You can combine XLOOKUP with other new formulas like FILTER() to create something crazy and fun too. Try it yourself. |
Chandoo | What is the net sales? | #N/A | XLOOKUP(H17,sales[Sales Person],sales[Net Sales]) | And of course, when the data can?t be found XLOOKUP simly #N/As |
How can I get XLOOKUP?
You can get it immediately, if you have Office 365 and signed up for insider program. The insider program is easy to sign up. Just open Excel (or other office applications) and go to File > Account and click on Office Insider and select “Change level”. Sign up for weekly updates and you are good to go.

When you sign up for insider program, Microsoft will release weekly new version to your computer. Be on the lookout for features that may disappear or change the look from week to week as MS will test things before launching them to wider audience.
Note: As per Joe McDaid‘s (Project Manager in Excel Team) latest tweet, if you are on insider program, then you should have access to XLOOKUP, so no need to wait.
Download XLOOKUP examples workbook
Click here to download the 13 XLOOKUP examples file. Kindly note that it will not work if you do not have XLOOKUP. So upgrade your office first.
Got XLOOKUP yet? Share your thoughts
Have you played with XLOOKUP yet? I have it for just under 3 hours now and I am super excited to use it. What about you? Please share your thoughts and creative uses of it in the comments section.
The post What is XLOOKUP? 13 formula examples to really understand it appeared first on Chandoo.org – Learn Excel, Power BI & Charting Online.
Original source: http://feedproxy.google.com/~r/PointyHairedDilbert/~3/e-OBoQdLZ6U/